Arduino(アルドゥイーノ)演習参照アドレスArduino(アルドゥイーノ)演習は下記のアドレスを参照します。
https://www.arduino.cc/en/Tutorial/HomePage
HC-SR04 超音波距離センサーモジュールの回路図HC-SR04 超音波距離センサーモジュールの回路図は以下となります。
HC-SR04 超音波距離センサーモジュールの動作原理（１）Trigにパルス幅10μsの正パルスを送ると超音波計測を開始します。
（２）超音波計測が完了すると超音波が往復する時間と等しい正パルスをEchoから送信します。
（３）従って、Echoの正パルスの時間幅を計測して、音速が一定として距離に換算します。
**音速は気温に依存するため、一定ではありませんが概算の距離を計算します。
HC-SR04 超音波距離センサーモジュールのスケッチ（１）メニューの「ファイル」＿「スケッチの例」＿「Sensors」＿「Ping」で基本形のスケッチが設定されます。
（２）HC-SR04 超音波距離センサーモジュールの仕様に基づいて下記のように修正します。（//**変更が変更箇所の目印です。）
/*
HC-SR04
Ping))) Sensor
This sketch reads a PING))) ultrasonic rangefinder and returns the
distance to the closest object in range. To do this, it sends a pulse
to the sensor to initiate a reading, then listens for a pulse
to return. The length of the returning pulse is proportional to
the distance of the object from the sensor.
The circuit:
* +V connection of the PING))) attached to +5V
* GND connection of the PING))) attached to ground
* SIG connection of the PING))) attached to digital pin 7
http://www.arduino.cc/en/Tutorial/Ping
created 3 Nov 2008
by David A. Mellis
modified 30 Aug 2011
by Tom Igoe
This example code is in the public domain.
*/
// this constant won't change. It's the pin number
// of the sensor's output:
const int pingPin = 7;
const int inPin = 8;//**変更（追加）
void setup() {
// initialize serial communication:
Serial.begin(9600);
}
void loop()
{
// establish variables for duration of the ping,
// and the distance result in inches and centimeters:
long duration, inches, cm;
// The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
// Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
pinMode(pingPin, OUTPUT);
digitalWrite(pingPin, LOW);
delayMicroseconds(2);
digitalWrite(pingPin, HIGH);
delayMicroseconds(10);//**変更（5→10）
digitalWrite(pingPin, LOW);
// The same pin is used to read the signal from the PING))): a HIGH
// pulse whose duration is the time (in microseconds) from the sending
// of the ping to the reception of its echo off of an object.
//pinMode(pingPin, INPUT);//**変更（削除）
pinMode(inPin,INPUT);//**変更（追加）
// duration = pulseIn(pingPin, HIGH);//**変更（削除）
duration = pulseIn(inPin, HIGH);//**変更（追加）
// convert the time into a distance
inches = microsecondsToInches(duration);
cm = microsecondsToCentimeters(duration);
Serial.print(inches);
Serial.print("in, ");
Serial.print(cm);
Serial.print("cm");
Serial.println();
delay(100);
}
long microsecondsToInches(long microseconds)
{
// According to Parallax's datasheet for the PING))), there are
// 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
// second). This gives the distance travelled by the ping, outbound
// and return, so we divide by 2 to get the distance of the obstacle.
// See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
return microseconds / 74 / 2;
}
long microsecondsToCentimeters(long microseconds)
{
// The speed of sound is 340 m/s or 29 microseconds per centimeter.
// The ping travels out and back, so to find the distance of the
// object we take half of the distance travelled.
return microseconds / 29 / 2;
}
HC-SR04 超音波距離センサーモジュールの実行（１）メニューの「スケッチ」＿「マイコンボードに書き込む」で書込みされ、実行されます。
（２）メニューの「ツール」＿「シリアルモニタ」を選択するとシリアルモニタが表示されます。
シリアルモニタには以下が表示されます。
54in, 140cm 54in, 139cm 54in, 139cm 54in, 139cm 54in, 139cm 54in, 140cm 54in, 138cm 54in, 139cm 54in, 138cm 54in, 139cm 54in, 139cm 54in, 140cm 54in, 139cm 54in, 138cm 52in, 134cm 52in, 134cm 51in, 131cm 52in, 132cm 52in, 132cm 55in, 140cm 54in, 140cm 54in, 139cm 54in, 138cm
HC-SR04 超音波距離センサーモジュールまとめ（１）duration = pulseIn(inPin, HIGH);は簡潔な記述でEchoのパルス幅の時間を計測できます。
（２）Echoのパルス幅の時間がわかれば、後は距離に換算するだけです。
（３）計測値はバラツキがあります。
４１章：Arduino(アルドゥイーノ)演習（LiquidCrystal/HelloWorld編）に行く。