18章:3Dサンプル(sketch_3D_Z_H_shape)H形鋼

    作成2015.12.07

     Processingの3D機能を利用して3D機械製図への応用を検討してみたいと思います。

  1. H形鋼の寸法図
     H形鋼の寸法図を以下に示します。



    *図18-1からわかるようにH形鋼の基本寸法はWとBとT1とT2とLの5個のパラメータで形状が決まります。
    *WとBとT1とT2とLはfloat型でmm単位で入力とします。


  2. 3Dサンプル(sketch_3D_Z_H_shape)H形鋼スケッチ
     3Dサンプル(sketch_3D_Z_H_shape)H形鋼スケッチは以下となります。
    //sketch_3D_Z_H_shape)H形鋼
    void setup()
    {
      size(400, 400, P3D);
    }
    
    void draw()
    {
      background(255, 255, 255);
      lights();
      ortho(-width/2, width/2, -height/2, height/2); // Same as ortho()
      translate(width / 2, height / 2);
      rotateY(map(mouseX, 0, width, -PI/1, PI/1));
      rotateX(map(mouseY, 0, height, PI/1, -PI/1));
      //noStroke();
      strokeWeight(0.5);
        
      fill(255, 255, 255);
      scale(1, 1,1);
      
      Z_H_shape(100,100,6,8,100);//H_shape H形鋼
    }
    
    void Z_H_shape(float H,float B,float T1,float T2,float L)//H_shape H形鋼
    {
      int Pn=13;//ポイント数
      float x1=B/2;
      float x2=T1/2;
      float y1=H/2;
      float y2=H/2-T2;
      
      float X[]={-x1,x1,x1,x2,x2,x1,x1,-x1,-x1,-x2,-x2,-x1,-x1};
      float Y[]={-y1,-y1,-y2,-y2,y2,y2,y1,y1,y2,y2,-y2,-y2,-y1};
      
      pushMatrix();
      Z_Side(Pn,X,Y,L);//側面
      translate(0,0,-L/2);
      Z_Polyon(Pn,X,Y);//多角形
      translate(0,0,L);
      Z_Polyon(Pn,X,Y);//多角形
      popMatrix();
    }
    
    void Z_Side(int Pn,float X[],float Y[],float L)//側面
    {
      int i;
      beginShape(QUAD_STRIP);
      for (i = 0; i < Pn; ++i)
      {
        vertex(X[i],Y[i], -L/2);
        vertex(X[i],Y[i], L/2);
      }
      endShape(CLOSE);
    }
    
    void Z_Polyon(int Pn,float X[],float Y[])//多角形
    {
      int i;
      beginShape();
      for (i = 0; i < Pn; ++i)
      {
        vertex(X[i],Y[i]);
      }
      endShape(CLOSE);
    }
    


  3. 3Dサンプル(sketch_3D_Z_H_shape)H形鋼テキストファイル
     3Dサンプル(sketch_3D_Z_H_shape)H形鋼テキストファイルテキストファイルは以下から参照できます。
    「3Dサンプル(sketch_3D_Z_H_shape)H形鋼テキストファイル」にいく



  4. 3Dサンプル(sketch_3D_Z_H_shape)H形鋼スケッチの実行
    (1)3Dサンプル(sketch_3D_Z_H_shape)H形鋼スケッチを実行すると実行ウインドウに3D画像が表示されます。
    (2)マウスを動かすと表示角度が変化します。
    (3)表示画像例を以下に示します。





  5. 3Dサンプル(sketch_3D_Z_H_shape)H形鋼まとめ
    (1)表示は正投影のortho(-width/2, width/2, -height/2, height/2);としました。
    (2)線有りのstrokeWeight(0.5);としました。
    (3)Z_H_shape(100,100,6,8,100);//H_shape H形鋼と指定すると指定寸法のH形鋼が表示できます。



19章:3Dサンプル(sketch_3D_Z_Channel)みぞ形鋼に行く。

トップページに戻る。